# MEC 3500 - FINITE ELEMENT ANALYS

Document Sample

```					   LECTURE 5
STRUCTURAL
ANALYSIS GUIDE
STRUCTURAL ANALYSIS’ IN
THE ‘STRUCTURAL ANALYSIS
GUIDE’ (30 MINS)

STRUCTURES INCLUDE
 Bridges
 Buildings
 Ship hulls
 Aircraft bodies
 Machine housings
 Pistons
 Machine parts
 etc
The primary unknowns in a
structural analysis are
DISPLACEMENTS

TYPES OF STRUCTURAL
ANALYSES:
 Static analysis
 Modal analysis
 Harmonic analysis
 Transient Dynamic analysis
 Spectrum analysis
 Buckling analysis
 Explicit Dynamic analysis

IN ANSYS WE CAN CARRY OUT
ANALYSIS INVOLVING
FRACTURE MECHANICS,
MECHANICAL FATIGUE,
COMPOSITE MATERIALS
ELEMENTS USED IN
STRUCTURAL ANALYSES
 Spar
 Beams
 Pipes
 2-D Solids
 3-D Solids
 Shells
 Interface
 Contact
 Coupled field
 Other special elements
STRUCTURAL STATIC
ANALYSIS:

STATIC ANALYSIS IS USED TO
DETERMINE THE
DISPLACEMENTS, STRESSES,
STRAINS, AND FORCES IN
STRUCTURES CAUSED BY
SIGNIFICANT INERTIA AND
DAMPING EFFECTS.

CAN BE APPLIED IN A STATIC
ANALYSIS INCLUDE:
   Externally applied forces and
pressures
(such as gravity)
   Imposed (nonzero)
displacements
   Temperatures (for thermal
strain)

WE CAN HAVE BOTH
LINEAR & NON-LINEAR
STATIC ANALYSES.

PERFORMING A
STRUCTURAL STATIC
ANALYSIS:

1. BUILD THE MODEL
2. SET SOLUTION CONTROLS
i. ANTYPE
ii.   NLGEOM
iii.    TIME
iv.    AUTOTS
v.    NSUBST
vi.    OUTRES
vii.    EQSLV
viii.    NEQIT
ix.    SSTIF
x.    NROPT
xi.    PSTRES
xii.    ERESX
i. Displacements
ii. Forces
iii. Pressures
iv. Temperatures

YOU CAN DEFINE LOADS ON THE
SOLID MODEL OR ON THE FINITE
ELMENT MODEL
4. SOLVE
5. REVIEW THE RESULTS
   Primary data:
   Nodal displacements (UX, UY, UZ,
ROTX, ROTY, ROTZ)
   Derived data:
   Nodal and element stresses
   Nodal and element strains
   Element forces
   Nodal reaction forces
   and so on

POSTPROCESSORS

POST1 & POST26

   POST1 is used to review results
over the entire model at specific
substeps (time-points). Commands
normally used are SET, PLDISP,
PRESOL, PRNSOL, PRRSOL,
FSUM, NFORCE, NSORT,
ESORT, PLNSOL (averaged) ,
PLESOL, ETABLE, PLETAB,
PLLS, PLVECT, PRVECT
   POST26 is used in nonlinear static
analyses to track specific result
items over the applied load history.

ANALYSIS’ IN THE
‘STRUCTURAL ANALYSIS
GUIDE’ (1 Hour)
WORK THROUGH ‘A SAMPLE
STATIC ANALYSIS’ IN
‘STRUCTURAL STATIC
ANALYSIS’ IN THE
‘STRUCTURAL ANALYSIS
GUIDE’ (2 Hours) – given below

/FILNAME,pm02!        Jobname to use for all subsequent files
/TITLE,Static analysis of an Allen wrench
/UNITS,SI       ! Reminder that the SI system of units is used
/SHOW           ! Specify graphics driver for interactive run; for batch
! run plots are written to pm02.grph

! Define parameters for future use

EXX=2.07E11        ! Young's modulus (2.07E11 Pa = 30E6 psi)
W_HEX=.01         ! Width of hex across flats (.01m=.39in)
*AFUN,DEG          ! Units for angular parametric functions
W_FLAT=W_HEX*TAN(30) ! Width of flat
L_SHANK=.075        ! Length of shank (short end) (.075m=3.0in)
L_HANDLE=.2         ! Length of handle (long end) (.2m=7.9 in)
L_ELEM=.0075        ! Element length (.0075 m = .30 in)
NO_D_HEX=2          ! Number of divisions on hex flat
TOL=25E-6         ! Tolerance for selecting nodes (25e-6 m = .001 in)

/PREP7
ET,1,SOLID45      ! Eight-node brick element
ET,2,PLANE42      ! Four-node quadrilateral (for area mesh)
MP,EX,1,EXX       ! Young's modulus for material 1
MP,PRXY,1,0.3     ! Poisson's ratio for material 1
RPOLY,6,W_FLAT ! Hexagonal area
K,7         ! Keypoint at (0,0,0)
K,8,,,-L_SHANK ! Keypoint at shank-handle intersection
K,9,,L_HANDLE,-L_SHANK         ! Keypoint at end of handle
L,4,1       ! Line through middle of hex shape
L,7,8       ! Line along middle of shank
L,8,9       ! Line along handle
/VIEW,,1,1,1   ! Isometric view in window 1
/ANGLE,,90,XM     ! Rotates model 90 degrees about X
/PNUM,LINE,1      ! Line numbers turned on
LPLOT
/PNUM,LINE,0      ! Line numbers off
L,1,4       ! Hex section is cut into two quadrilaterals
ASBL,1,7,,,KEEP ! to satisfy mapped meshing requirements for bricks
CM,BOTAREA,AREA ! Component name BOTAREA for the two areas

! Generate area mesh for later drag

LESIZE,1,,,NO_D_HEX        ! Number of divisions along line 1
LESIZE,2,,,NO_D_HEX
LESIZE,6,,,NO_D_HEX
TYPE,2             ! PLANE42 elements to be meshed first
MSHKEY,1
SAVE              ! Save database before meshing
AMESH,ALL
/TITLE,Meshed hex wrench end to be used in vdrag
EPLOT

! Now drag the 2-D mesh to produce 3-D elements

TYPE,1            ! Type pointer set to SOLID45
ESIZE,L_ELEM           ! Element size
VDRAG,2,3,,,,,8,10,9 ! Drag operation to create 3-D mesh
/TYPE,,HIDP          ! Precise hidden line display
/TITLE,Meshed hex wrench
EPLOT
CMSEL,,BOTAREA             ! Select BOTAREA component and
ACLEAR,ALL            !    delete the 2-D elements
ASEL,ALL
FINISH

! Apply loads and obtain the solution

/SOLU
ANTYPE,STATIC             ! Static analysis (default)
/TITLE,Allen wrench -- Load step 1

! First fix all nodes around bottom of shank

CMSEL,,BOTAREA             ! Bottom areas of shank
LSEL,,EXT           ! Exterior lines of those areas
NSLL,,1           ! Nodes on those lines
D,ALL,ALL           ! Displacement constraints
LSEL,ALL
/PBC,U,,1          ! Displacement symbols turned on
/TITLE,Boundary conditions on end of wrench
NPLOT

!Now apply pressure on handle to represent 100-N (22.5-lb) finger force

ASEL,R,LOC,X,W_FLAT/2,W_FLAT              ! Two areas on one side of handle...
NSLA,,1                   ! ...and all corresponding nodes
NSEL,R,LOC,Y,L_HANDLE+TOL,L_HANDLE-(3.0*L_ELEM)-TOL ! Reselects nodes at
! back end of handle (3 element lengths)
*GET,MINYVAL,NODE,,MNLOC,Y               ! Get minimum Y value of selected nodes
*GET,MAXYVAL,NODE,,MXLOC,Y                ! Get maximum Y value of selected nodes
PTORQ=100/(W_HEX*(MAXYVAL-MINYVAL)) ! Pressure equivalent to 100 N
SF,ALL,PRES,PTORQ                  ! PTORQ pressure on all selected nodes
ALLSEL                    ! Restores full set of all entities
/PSF,PRES,,2                 ! Pressure symbols turned on
/TITLE,Boundary conditions on wrench for load step 1
NPLOT
LSWRITE                    ! Writes first load step
/TITLE, Allen wrench -- load step 2
! Downward pressure on top of handle, representing 20-N (4.5 -lb) force

PDOWN=20/(W_FLAT*(MAXYVAL-MINYVAL))

ASEL,,LOC,Z,-(L_SHANK+(W_HEX/2)) ! Area on top flat of handle...
NSLA,,1                     ! ...and all corresponding nodes
NSEL,R,LOC,Y,L_HANDLE+TOL,L_HANDLE-(3.0*L_ELEM)-TOL ! Reselects nodes at
! back end of handle (3 element lengths)
SF,ALL,PRES,PDOWN                   ! PDOWN pressure at all selected nodes
ALLSEL
/TITLE,Boundary conditions on wrench for load step 2
NPLOT
LSWRITE                     ! Writes second load step
SAVE                      ! Save database before solution
LSSOLVE,1,2              ! Initiates solution for load step files 1 and 2
FINISH

!Review the results

/POST1
PRRSOL                 ! Reaction solution listing
/PBC,DEFA              ! No BC symbols
/PSF,DEFA              ! No surface load symbols
/EDGE,,1              ! Edges only, no interior element outlines
/TITLE,Deformed allen wrench caused by torque
PLDISP,2              ! Deformed shape overlaid with undeformed edge plot
/GSAVE,pldisp,gsav        ! Saves graphics specifications on pldisp.gsav
/PLOPTS,INFO,ON             ! Turns on entire legend column
/PLOPTS,LEG1,OFF            ! Turns off legend header
/ANGLE,,120,YM,1          ! Additional rotation about model Y (to see high stress areas)
/TITLE,Stress intensity contours caused by torque
PLNSOL,S,INT             ! Stress intensity contours
/GSAVE,plnsol,gsav        ! Saves graphics specifications to plnsol.gsav
PRRSOL                 ! Reaction solution listing
/GRESUME,pldisp,gsav         ! Resumes graphics specifications from pldisp.gsav
/TITLE,Deformed allen wrench caused by torque and force
PLDISP,2
/GRESUME,plnsol,gsav         ! Resumes graphics specifications from plnsol.gsav
/TITLE,Stress intensity contours caused by torque and force
PLNSOL,S,INT
WPOF,,,-0.067        ! Offset the working plane for cross-section view
/TYPE,1,5          ! Capped hidden display
/CPLANE,1           ! Cutting plane defined to use the WP
/VIEW, 1 ,WP        ! View will be normal to the WP
/DIST,1,.01        ! Zoom in on the cross section
PLNSOL,S,INT
FINISH

/EXIT,ALL

ANOTHER EXAMPLE:
FEA1 – COURSEWORK TEST 2 – JANUARY 2004
TIME ALLOWED 2.5 Hours

You are reminded to concentrate only on your work during the test. Failure to do so may result in
some marks being deducted.
IMPORTANT NOTE : Here you are faced with a real design problem – an open ended problem –
in which you have to start working on the problem and improve on it. I think that you will not
have enough time (and energy) to finish the problem in the allowed time unless you happen to hit
on the right way of approach immediately. Do your best during the test – you may even finish the
problem if you really concentrate ……………. But allow 15 minutes at the end to give me a
description on how you would re-tackle the problem once you have worked through it once.
Hand in a file of your work on a floppy disc and a hard copy version of it (if possible).
To accompany your work you must also hand in a hand-written report in which you can include
sketches.

Given the socket and specifications shown in Figure 1, build a finite element model
of the socket (6 marks) and perform a static structural stress analysis. You have to

In the hand-written report describe
(i) the element used (2 marks)
(ii) the assumptions taken, etc. (8 marks)

From your analysis deduce the position/s of the weakest point or points of the socket.
State the maximum von Mises stress reached in the socket and where it occurs.
(9 marks)

Figure 1

OTHER EXAMPLES

Beam problem

Thick cylinder
Thin cylinder